home *** CD-ROM | disk | FTP | other *** search
/ Wonky Flux Batch 2019 02 / Wonky_Flux_Batch_2019-02.zip / Wonky Flux Batch 2019-02 / 021 - HO Utilities - Clock Utility System.dsk / TIME.LIMIT.QUIZ.bas < prev    next >
BASIC Source File  |  2019-02-16  |  2KB  |  41 lines
  1. 10  REM TIME LIMIT QUIZ
  2. 20 D$ =  CHR$(4): PRINT D$"BLOAD BIN.MILLISEC"
  3. 30  CALL 768: REM SET UP INTERRUPTS
  4. 40  IF  PEEK(784) = 0  THEN  PRINT "TIMEMASTER NOT FOUND": END 
  5. 50 B$ =  CHR$(7):NQ = 0
  6. 60 NQ = NQ +1
  7. 70  GOSUB 1000: REM PRESENT NEXT QUESTION
  8. 80  GOSUB 2000: REM WAIT UP TO 5 SECONDS FOR ANSWER
  9. 90  IF A$ = ""  THEN  PRINT B$"...TIMES UP!!!"B$: FOR I = 1 TO 3000: NEXT : GOTO 60
  10. 100  GOSUB 3000: REM JUDGE ANSWER
  11. 110  FOR I = 1 TO 5000: NEXT 
  12. 120  GOTO 60
  13. 1000  REM PRESENT NEXT QUESTION
  14. 1010  TEXT : HOME 
  15. 1020  READ A$: IF A$ = "."  THEN  PRINT "THAT'S ALL, FOLKS!!!": CALL 777: FOR I = 1 TO 5000: NEXT : POP : END 
  16. 1030  PRINT NQ".  "A$: FOR I = 1 TO 4: READ A$: PRINT "    " CHR$(I +192)".  "A$: NEXT 
  17. 1040  READ W$: REM CORRECT ANSWER
  18. 1050  READ TL:TL = TL *1024: REM  TIME LIMIT
  19. 1060  RETURN 
  20. 2000  REM WAIT UP TO 5 SECONDS FOR ANSWER
  21. 2005 T = 0: CALL 771: REM RESET TIMER
  22. 2010  IF  PEEK( -16384) >128  THEN 2050
  23. 2015 P =  PEEK( -16336) + PEEK( -16336) + PEEK( -16336)
  24. 2020  CALL 774: REM  SAVE CURRENT COUNT
  25. 2030 T =  PEEK(782) *256 + PEEK(783): IF T <TL  THEN 2010
  26. 2040 A$ = "": RETURN : REM TIMED OUT
  27. 2050  GET A$: PRINT A$: RETURN 
  28. 3000  REM JUDGE ANSWER
  29. 3010  IF A$ = W$  THEN 3200: REM  CORRECT ANSWER
  30. 3020  IF T <.4 *TL  THEN  PRINT "SORRY...DON'T BE IN SUCH A RUSH!": GOTO 3040
  31. 3030  PRINT "NO, THAT'S WRONG!": PRINT "THE ANSWER SHOULD BE '"W$"'.": RETURN 
  32. 3040  PRINT "THE ANSWER SHOULD BE '"W$"'.": RETURN 
  33. 3200  IF T <.4 *TL  THEN  PRINT "GREAT!": PRINT "AND YOU GOT IT IN ONLY " INT(T/256)/4" SECONDS!": RETURN 
  34. 3210  IF T <.8 *TL  THEN  PRINT "THAT'S RIGHT!": PRINT "IT TOOK YOU " INT(T/256)/4" SECONDS.": RETURN 
  35. 3220  IF T >TL  THEN T = TL
  36. 3230  PRINT "OKAY, THAT'S THE RIGHT ANSWER.": PRINT " BUT YOU MIGHT MOVE A LITTLE FASTER.": PRINT "IT TOOK YOU " INT(T/256)/4" SECONDS.": RETURN 
  37. 5000  DATA  "WHAT IS THE CAPITAL OF TEXAS?","HOUSTON","AUSTIN","DALLAS","SAN ANTONIO",B,5
  38. 5010  DATA  "WHO DESIGNED THE APPLE II?","STEVE JOBS","ARNOLD PALMER","STEVE WOZNIAK","PETER WEIGLIN",C,6
  39. 5020  DATA   "WHICH CHIP IS IN THE APPLE II?","68000","8088","Z-80","6502",D,10
  40. 5030  DATA  "WHO MAKES THE BEST APPLE CLOCK CARD?","APPLIED ENGINEERING","MOUNTAIN HARDWARE","THUNDERWARE","APPLE COMPUTER",A,5
  41. 5999  DATA "."